UnityShader学习笔记-高光反射基础光照模型

1222 words

6 minutes

UnityShader学习笔记-高光反射基础光照模型

2025-06-14

UnityShader

Unity

/

Shader

高光反射#

定义#

高光反射（镜面反射）是指物体表面上沿特定方向镜面反射光线而形成的、随观察角度变化的高亮区域，用于在渲染过程中光滑表面对光线的精面反射现象
高光反射是实时光照模型中的重要组成，主要用于表现物体表面的“光滑程度”和“材质质感”

高光反射示意图

反射公式#

根据高光反射示意图，将示意图中的表面法向量、光源方向向量、反射方向向量进行归一化处理，并在二维坐标系中进行计算，如下图所示：

反射数学模型

根据图中向量关系，可以推导出反射公式，推导过程如下图所示：

reflect = lightDir - 2 * normal * (dot(lightDir, normal))

反射公式推导

高光反射基础光照模型#

着色器基础结构#

根据高光反射计算公式：

c_{reflect} = (c_{light}\cdot{m_{specular}})max(0, \vec{v}\cdot{\vec{r}})^{m_{gloss}}

从公式中可以看出需要五个参数：

入射光线颜色和强度： $c_{light}$
高光反射系数： $m_{specular}$
视角向量： $\vec{v}$
反射向量： $\vec{r}$ ，可通过 reflect(I, N)函数计算获得
光泽度： $m_{gloss}$ ，用于控制高光反射区域的大小

基于上述参数，我们可以在着色器中设置相关可调属性：

1
Properties
2
{
3
    _Diffuse ("漫反射颜色", Color) = (1, 1, 1, 1)
4
    _Specular ("高光反射颜色", Color) = (1, 1, 1, 1)
5
    _Gloss ("光泽度", Range(8.0, 256)) = 20
6
}

逐顶点光照#

原理：和漫反射光照一样，在顶点着色器中计算光照（漫反射+高光反射），并将结果通过插值传递给片段着色器。

1
Shader "Custom/SpecularVertexLevel"
2
{
3
    Properties
4
    {
5
        _Diffuse ("漫反射颜色", Color) = (1, 1, 1, 1)
6
        _Specular ("高光反射颜色", Color) = (1, 1, 1, 1)
7
        _Gloss ("光泽度", Range(8.0, 256)) = 20
8
    }
9

10
    SubShader
11
    {
12
        Pass
13
        {
14
            Tags {"LightMode" = "ForwardBase"}
15

16
            CGPROGRAM
17

18
            #pragma vertex vert
19
            #pragma fragment frag
20

21
            #include "Lighting.cginc"
22

23
            fixed4 _Diffuse;
24
            fixed4 _Specular;
25
            float _Gloss;
26

27
            struct a2v
28
            {
29
                float4 vertex : POSITION;
30
                float3 normal : NORMAL;
31
            };
32

33
            struct v2f
34
            {
35
                float4 pos : SV_POSITION;
36
                fixed3 color : COLOR;
37
            };
38

39
            v2f vert(a2v v)
40
            {
41
                //获取环境光的颜色和强度
42
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
43
                //将法向量从模型空间坐标转成投影空间坐标
44
                fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
45
                //获取光源方向
46
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
47
                //计算漫反射强度
48
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
49
                //获取反射方向
50
                fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
51
                //获取视角方向
52
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);
53
                //计算高光反射
54
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
55

56
                v2f o;
57
                //将顶点从模型空间坐标转成投影空间坐标
58
                o.pos = UnityObjectToClipPos(v.vertex);
59
                //颜色 = 环境光 + 漫反射 + 高光反射
60
                o.color = ambient + diffuse + specular;
61

62
                return o;
63
            }
64

65
            fixed4 frag(v2f i) : SV_Target
66
            {
67
                return fixed4(i.color, 1.0);
68
            }
69

70
            ENDCG
71
        }
72
    }
73
    FallBack "Specular"
74
}

逐顶点光照

从图上可以看出，高光反射在逐顶点光照中表现的明显不够平滑，主要原因是高光反射的计算是非线性的，而在顶点着色器中的插值都是线性的，导致非线性计算关系被破坏了。

逐像素光照#

原理：在顶点着色器中计算每个顶点在裁剪空间中的顶点坐标、计算在世界空间中的法向量和顶点坐标，然后传递给片元着色器，在片元着色器中计算光照（漫反射+高光反射），并返回颜色。

1
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
2

3
Shader "Custom/SpecularPixelLevel"
4
{
5
    Properties
6
    {
7
        _Diffuse ("漫反射颜色", Color) = (1, 1, 1, 1)
8
        _Specular ("高光反射颜色", Color) = (1, 1, 1, 1)
9
        _Gloss ("光泽度", Range(8.0, 256)) = 20
10
    }
11

12
    SubShader
13
    {
14
        Pass
15
        {
16
            Tags {"LightMode" = "ForwardBase"}
17

18
            CGPROGRAM
19

20
            #pragma vertex vert
21
            #pragma fragment frag
22

23
            #include "Lighting.cginc"
24

25
            fixed4 _Diffuse;
26
            fixed4 _Specular;
27
            float _Gloss;
28

29
            struct a2v
30
            {
31
                float4 vertex : POSITION;
32
                float3 normal : NORMAL;
33
            };
34

35
            struct v2f
36
            {
37
                float4 pos : SV_POSITION;
38
                float3 worldNormal : TEXCOORD0;
39
                fixed3 worldPos : TEXCOORD1;
40
            };
41

42
            v2f vert(a2v v)
43
            {
44
                v2f o;
45
                //将顶点从模型空间坐标转成投影空间坐标
46
                o.pos = UnityObjectToClipPos(v.vertex);
47
                o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
48
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
49

50
                return o;
51
            }
52

53
            fixed4 frag(v2f i) : SV_Target
54
            {
55
                //获取环境光的颜色和强度
56
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
57

58
                //获取世界坐标系下的法向量
59
                fixed3 worldNormal = normalize(i.worldNormal);
60
                //获取光源方向
61
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
62
                //计算漫反射强度
63
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
64

65
                //获取反射方向
66
                fixed3 reflectDir = normalize(reflect(-worldLightDir, worldNormal));
67
                //获取视角方向
68
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
69
                //计算高光反射
70
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
71

72
                fixed3 color = ambient + diffuse + specular;
73
                return fixed4(color, 1.0);
74
            }
75

76
            ENDCG
77
        }
78
    }
79
    FallBack "Specular"
80
}