UnityShader学习笔记-BlinnPhone模型

578 words

3 minutes

UnityShader学习笔记-BlinnPhone模型

2025-06-15

UnityShader

Unity

/

Shader

BlinnPhone模型#

BlinnPhone示意图

在Phone模型中，需要计算反射方向向量来计算高光反射。因此在BlinnPhone模型中，定义了一个半程向量（Halfway Vector），即光线方向向量和视角方向向量夹角的一半的单位向量，来避免计算反射方向向量，其公式如下：

\vec{h} = \frac{\vec{l} + \vec{v}}{|\vec{l} + \vec{v}|}

BlinnPhone模型的高光反射模的公式如下:

c_{specular} = (c_{light}\cdot{m_{specular}})max(0, \vec{n}\cdot{\vec{h}})^{m_{gloss}}

从公式中可以看出需要五个参数：

入射光线颜色和强度： $c_{light}$
高光反射系数： $m_{specular}$
表面法向量： $\vec{n}$
半程向量： $\vec{h}$ ，可通过半程向量公式计算获得
光泽度： $m_{gloss}$ ，用于控制高光反射区域的大小

BlinnPhone光照#

原理：整体同逐像素光照的高光反射的着色器，仅在计算高光反射时使用BlinnPhone的高光反射公式

1
Shader "Custom/BlinnPhone"
2
{
3
    Properties
4
    {
5
        _Diffuse ("漫反射颜色", Color) = (1, 1, 1, 1)
6
        _Specular ("高光反射颜色", Color) = (1, 1, 1, 1)
7
        _Gloss ("光泽度", Range(8.0, 256)) = 20
8
    }
9

10
    SubShader
11
    {
12
        Pass
13
        {
14
            Tags {"LightMode" = "ForwardBase"}
15

16
            CGPROGRAM
17

18
            #pragma vertex vert
19
            #pragma fragment frag
20

21
            #include "Lighting.cginc"
22

23
            fixed4 _Diffuse;
24
            fixed4 _Specular;
25
            float _Gloss;
26

27
            struct a2v
28
            {
29
                float4 vertex : POSITION;
30
                float3 normal : NORMAL;
31
            };
32

33
            struct v2f
34
            {
35
                float4 pos : SV_POSITION;
36
                float3 worldNormal : TEXCOORD0;
37
                fixed3 worldPos : TEXCOORD1;
38
            };
39

40
            v2f vert(a2v v)
41
            {
42
                v2f o;
43
                //将顶点从模型空间坐标转成投影空间坐标
44
                o.pos = UnityObjectToClipPos(v.vertex);
45
                o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
46
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
47

48
                return o;
49
            }
50

51
            fixed4 frag(v2f i) : SV_Target
52
            {
53
                //获取环境光的颜色和强度
54
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
55

56
                //获取世界坐标系下的法向量
57
                fixed3 worldNormal = normalize(i.worldNormal);
58
                //获取光源方向
59
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
60
                //计算漫反射强度
61
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLightDir));
62

63
                //获取视角方向
64
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
65
                //获取反射方向
66
                fixed3 halfDir = normalize(worldLightDir + viewDir);
67
                //计算高光反射(BlinnPhone模型)
68
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
69

70
                fixed3 color = ambient + diffuse + specular;
71
                return fixed4(color, 1.0);
72
            }
73

74
            ENDCG
75
        }
76
    }
77
    FallBack "Specular"
78
}